drdroidapi-java/build.gradle at main · DrDroidLab/drdroidapi-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'maven-publish'
apply plugin: 'signing'

group = "io.drdroid"
archivesBaseName = "api-java"
version = "2.0.2"

repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    // https://mvnrepository.com/artifact/com.google.guava/guava
    implementation group: 'com.google.guava', name: 'guava', version: 'r05'

    //To make disk backed
    // http://square.github.io/tape/
    implementation group: 'com.squareup', name: 'tape', version: '1.2.3'

    //HTTP api call dependency
    implementation('com.squareup.retrofit:retrofit:2.0.0-beta2')
    implementation('com.squareup.retrofit:converter-jackson:2.0.0-beta2')

    testImplementation group: 'junit', name: 'junit', version: '4.12'
    testImplementation group: 'org.mockito', name: 'mockito-all', version: '1.10.19'
    testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: '5.9.1'
    testImplementation group: 'org.mock-server', name: 'mockserver-netty-no-dependencies', version: '5.14.0'
    testImplementation group: 'org.awaitility', name: 'awaitility', version: '3.0.0'
}


test {
    useJUnitPlatform()
}

java {
    withJavadocJar()
    withSourcesJar()
}

publishing {
    publications {

        mavenJava(MavenPublication) {

            groupId = "io.drdroid"
            artifactId = "api-java"
            version = "2.0.2"

            from components.java

            pom {
                name = 'DrDroid Java SDK'
                description = 'DrDroid Java API to connect with DrDroid Backend.'
                url = 'https://github.com/orgs/DrDroidLab'
                inceptionYear = '2023'

                licenses {
                    license {
                        name = 'MIT License'
                        url = 'http://www.opensource.org/licenses/mit-license.php'
                    }
                }
                developers {
                    developer {
                        id = 'droid-mohit'
                        name = 'Mohit Goyal'
                        email = 'mohit.goyale@drdroid.io'
                    }
                }
                scm {
                    connection = 'scm:git:git:github.com/DrDroidLab/drdroidapi-java.git'
                    developerConnection = 'scm:git:https://github.com/DrDroidLab/drdroidapi-java.git'
                    url = 'https://github.com/DrDroidLab/drdroidapi-java'
                }
            }
        }
    }

    repositories {
        maven {
            name = "OSSRH"
            def releasesRepoUrl = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
            def snapshotsRepoUrl = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
            url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
            credentials {
                username = project.ossrhUsername
                password = project.ossrhPassword
            }
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}