teamcity-gitlab-issues/build.gradle at master · Deroin/teamcity-gitlab-issues · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
import org.apache.tools.ant.filters.ReplaceTokens

group = 'de.dero'
version = '1.1-SNAPSHOT'

ext {
    teamCityVersion = '10.0.2'
}

apply plugin: 'java'
apply plugin: 'idea'

configurations {
    provided
}

sourceSets {
    main {
        compileClasspath += configurations.provided
    }
}

idea {
    module {
        scopes.PROVIDED.plus += [configurations.provided]
    }
}

repositories {
    mavenCentral()
    maven {
        url "http://repository.jetbrains.com/all"
    }
}

dependencies {
    compile "org.gitlab:java-gitlab-api:1.2.7"
    provided "org.jetbrains.teamcity:server-api:$teamCityVersion"
    provided "org.jetbrains.teamcity:server-web-api:$teamCityVersion"
    testRuntime "org.jetbrains.teamcity:tests-support:$teamCityVersion"
}

task createBundle(type: Zip, dependsOn: build) {
    from("${rootDir}/teamcity-plugin.xml") {
        filter(ReplaceTokens, tokens: [Version: project.version])
    }

    from(jar) {
        into 'server'
    }

    configurations.compile.resolvedConfiguration.firstLevelModuleDependencies.each {
        it.allModuleArtifacts.each {
            from(it.getFile().getPath()) {
                into 'server'
            }
        }
    }
}