rdap/build.gradle at master · DNSBelgium/rdap · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
plugins {
    id 'java'
    id 'net.researchgate.release' version '3.1.0'
    id 'org.sonarqube' version '6.3.1.5724'
    id 'com.vanniktech.maven.publish' version '0.34.0'
}

ext {
    guava_version = '32.1.3-jre'
    slf4j_version = '2.0.9'
    jackson_version = '2.15.3'
    spring_version = '6.0.13'

    lib = [
            icu4j                 : 'com.ibm.icu:icu4j:73.2',
            guava                 : "com.google.guava:guava:${guava_version}",
            commons_lang          : 'org.apache.commons:commons-lang3:3.13.0',
            commons_text          : 'org.apache.commons:commons-text:1.14.0',
            servlet_api           : 'jakarta.servlet:jakarta.servlet-api:6.0.0',
            joda_time             : 'joda-time:joda-time:2.12.5',
            junit                 : 'junit:junit:4.13.2',
            slf4j                 : "org.slf4j:slf4j-api:${slf4j_version}",
            jackson               : ["com.fasterxml.jackson.core:jackson-core:${jackson_version}", "com.fasterxml.jackson.core:jackson-databind:${jackson_version}"],
            mockito               : 'org.mockito:mockito-core:5.5.0',
            jsonpath              : 'com.jayway.jsonpath:json-path:2.8.0',
            spring_core           : "org.springframework:spring-core:${spring_version}",
            spring_webmvc         : "org.springframework:spring-webmvc:${spring_version}",
            spring_web            : "org.springframework:spring-web:${spring_version}",
            spring_test           : "org.springframework:spring-test:${spring_version}",
            groovy                : 'org.codehaus.groovy:groovy:3.0.19',
    ]
}

allprojects {
    group = 'be.dnsbelgium'
}

subprojects {

    apply plugin: 'java-library'
    apply plugin: 'jacoco'
    apply plugin: 'com.vanniktech.maven.publish'

    repositories {
        mavenCentral()
    }

    test {
        //forkEvery = 5
        //maxParallelForks = Runtime.runtime.availableProcessors() - 1
        systemProperties 'file.encoding': 'UTF-8'
        testLogging {
            //exceptionFormat "full"
            //events 'started', 'passed', 'skipped', 'failed'
        }
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = 'UTF-8'
        //options.compilerArgs << "-Xlint:all"
    }

    tasks.withType(Javadoc).configureEach {
        options.addStringOption('Xdoclint:none', '-quiet')
    }

    mavenPublishing {
        publishToMavenCentral()

        signAllPublications()

        coordinates(group.toString(), project.name, version.toString())

        pom {
            name = 'RDAP ' + project.name
            description = 'RDAP implementation'
            url = 'https://github.com/DNSBelgium/rdap'
            licenses {
                license {
                    name = 'The Apache Software License, Version 2.0'
                    url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    distribution = 'repo'
                }
            }
            developers {
                developer {
                    id = 'dnsbelgium'
                    name = 'DNS Belgium Engineering'
                    email = 'engineering@dnsbelgium.be'
                    organization = 'DNS Belgium'
                    organizationUrl = 'https://www.dnsbelgium.be'
                }
            }
            scm {
                connection = 'scm:git@github.com:DNSBelgium/rdap.git'
                developerConnection = 'scm:git@github.com:DNSBelgium/rdap.git'
                url = 'scm:git@github.com:DNSBelgium/rdap.git'
            }
        }
    }

    release {
        git {
            requireBranch.set('master')
        }
    }

    afterReleaseBuild.dependsOn publishToMavenCentral

}