TelegramBotApiMock/build.gradle at master · Chase22/TelegramBotApiMock · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
plugins {
    id 'java-library'
    id 'groovy'
    id 'jacoco'
    id "org.jetbrains.kotlin.jvm" version "1.3.50"
}

apply plugin: 'idea'

repositories {
    mavenCentral()
    jcenter()
}

group = 'io.github.Chase22.telegram'
version = '1.0.0-SNAPSHOT'

final JACKSON_VERSION = '2.10.0'

sourceSets {
    integrationTest {
        compileClasspath += sourceSets.main.output
        runtimeClasspath += sourceSets.main.output
    }
}

idea {
    module {
        sourceDirs -= project.sourceSets.integrationTest.groovy.srcDirs
        testSourceDirs += project.sourceSets.integrationTest.groovy.srcDirs
        testSourceDirs += project.sourceSets.integrationTest.resources.srcDirs
    }
}

configurations {
    integrationTestImplementation.extendsFrom implementation
    integrationTestRuntimeOnly.extendsFrom runtimeOnly
}

dependencies {
    implementation 'io.undertow:undertow-core:2.0.27.Final'
    implementation 'org.slf4j:slf4j-api:1.7.28'

    implementation "com.fasterxml.jackson.core:jackson-databind:${JACKSON_VERSION}"
    implementation "com.fasterxml.jackson.module:jackson-module-kotlin:${JACKSON_VERSION}"

    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-core:1.0.1'

    // Use the latest Groovy version for Spock testing
    testImplementation 'org.codehaus.groovy:groovy-all:2.5.7'
    testImplementation 'org.spockframework:spock-core:1.3-groovy-2.5'
    testImplementation 'org.objenesis:objenesis:3.0.1'
    testImplementation 'cglib:cglib-nodep:3.2.9'
    testImplementation 'junit:junit:4.12'

    testImplementation group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.12.1'

    integrationTestImplementation 'org.codehaus.groovy:groovy-all:2.5.7'
    integrationTestImplementation 'org.spockframework:spock-core:1.3-groovy-2.5'
    integrationTestImplementation 'junit:junit:4.12'

    integrationTestImplementation 'org.telegram:telegrambots:4.9.1'

    integrationTestImplementation 'org.apache.logging.log4j:log4j-slf4j-impl:2.12.1'
    integrationTestImplementation 'org.gebish:geb-waiting:2.2'
}

task integrationTest(type: Test) {
    description = 'Runs integration tests.'
    group = 'verification'

    testClassesDirs = sourceSets.integrationTest.output.classesDirs
    classpath = sourceSets.integrationTest.runtimeClasspath
    shouldRunAfter test
}

check.dependsOn integrationTest

jacocoTestReport {
    reports {
        html.enabled true
        xml.enabled true
    }
}

test {
    finalizedBy jacocoTestReport
}