Keep attached part

[RoettingerJ]

How can I prevent that the bottom chamfer will be removed from the rip ?

include <BOSL2/std.scad>
include <BOSL2/rounding.scad>
include <BOSL2/walls.scad>
include <BOSL2/screws.scad>
include <BOSL2/threading.scad>
include <BOSL2/structs.scad>

/*[ Hidden ]*/
$fn = $preview ? 32 : 64;

/* [ View ] */
printLayout = false;
cut = 0;
cutDistance = 0;
cutSize = 100;

/* [ Parameters ] */
boxInnerDimensions = [140, 80];
boxInnerTopHeight = 15;
boxInnerBottomHeight = 30;
boxOuterCornerRadius = 2;
boxOuterBottomChamfer = 2;
boxInnerCornerRadius = 1;
boxInnerBottomChamfer = 1;
boxThickness = 3;
sealDimensions = [1.5, 1.5];
sealWallThickness = 1.5;
sealExtensionHeight = 6;
ribThickness = 5;

bid = boxInnerDimensions;
bith = boxInnerTopHeight;
bibh = boxInnerBottomHeight;
bocr = boxOuterCornerRadius;
bobc = boxOuterBottomChamfer;
bicr = boxInnerCornerRadius;
bibc = boxInnerBottomChamfer;
bt = boxThickness;
sld = sealDimensions;
slwt = sealWallThickness;
sleh = sealExtensionHeight;
rt = ribThickness;

bt2 = bt * 2;
slwt2 = slwt * 2;
sleod = concat(bid, 0) + [(sld.x+slwt2)*2, (sld.x+slwt2)*2, sleh];
slcr = bocr + sld.x + slwt2 - bt;
slcd = [sld.x+slwt2-bt, sleh-sld.y];

difference() {
  parts();
  if (cut != 0 && !printLayout) {
    move(cut*cutDistance) cuboid(cutSize, anchor=cut);
  }
}

module parts() {
  bottomPart();
  topPart();
}

module bottomPart() {
  id = [bid.x, bid.y, bibh];
  od = id + [bt2, bt2, bt];

  diff()
    baseBox(d=od, cr=bocr, bc=bobc, anchor=BOTTOM) {
      position(TOP) ripsY(h=od.z, anchor=TOP);
      position(TOP) baseBox(d=sleod, cr=slcr, bc=slcd, anchor=TOP);
      tag("remove") up(0.01) position(TOP) baseBox(d=id, cr=bicr, bc=bibc, anchor=TOP);
    }
}

module topPart() {
  
}

module ripsY(h, anchor) {
  d = [sleod.x, rt, h];
  tag_scope() {
    diff()
      cuboid(d, anchor=anchor)
        children();
  }
}


module baseBox(d, cr, bc, anchor) {
  bcx = is_vector(bc) ? bc.x : bc;
  bcy = is_vector(bc) ? bc.y : bc;

  tag_scope() {
    diff()
      cuboid(d, rounding=cr, edges=["Z"], anchor=anchor) {
        tag("remove") face_profile(BOTTOM, r=cr) mask2d_chamfer(x=bcx, y=bcy);
        children();
    }
  }
}

[RoettingerJ]

Finally found the solution by making an attachable with own tag scope

module baseBox(d, cr, bc, anchor) {
  bcx = is_vector(bc) ? bc.x : bc;
  bcy = is_vector(bc) ? bc.y : bc;

  attachable(anchor=anchor, size=d) {
    tag_scope() 
      diff()
        cuboid(d, rounding=cr, edges=["Z"]) {
          tag("remove") face_profile(BOTTOM, r=cr) mask2d_chamfer(x=bcx, y=bcy);
        }
      children();
    }
}