build.gradle

buildscript {
	repositories {
		mavenCentral()
	}
	dependencies {
		classpath "org.flywaydb:flyway-database-postgresql:11.1.0"
	}
}

plugins {
	id 'org.jetbrains.kotlin.jvm' version '1.9.25'
	id 'org.jetbrains.kotlin.plugin.spring' version '1.9.25'
	id 'org.jetbrains.kotlin.kapt' version '1.9.25'
	id 'org.springframework.boot' version '3.3.5'
	id 'io.spring.dependency-management' version '1.1.6'
	id 'org.jetbrains.kotlin.plugin.jpa' version '1.9.25'
	id 'com.ncorti.ktfmt.gradle' version '0.21.0'
	id 'org.flywaydb.flyway' version '11.1.0'
	id 'co.uzzu.dotenv.gradle' version '4.0.0'
}

// plugin config
ktfmt {
	kotlinLangStyle()
}

flyway {
	url = env.fetch('JDBC_DATABASE_URL', '')
	user = env.fetch('JDBC_DATABASE_USERNAME', '')
	password = env.fetch('JDBC_DATABASE_PASSWORD', '')
}

group = 'iterative.harmony'
version = '0.1' // Semantic versioning: MAJOR.MINOR

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

dependencies {
	developmentOnly 'org.springframework.boot:spring-boot-devtools'

	implementation "org.mapstruct:mapstruct:1.5.3.Final"
	kapt "org.mapstruct:mapstruct-processor:1.5.3.Final"
	implementation 'me.paulschwarz:spring-dotenv:4.0.0'
	implementation 'org.springframework.boot:spring-boot-starter-actuator'
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-mail'
	implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'
	implementation 'org.springframework.boot:spring-boot-starter-security'
	implementation 'org.springframework.boot:spring-boot-starter-validation'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	implementation 'org.springframework.boot:spring-boot-starter-webflux'
	implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:1.8.1"
	implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-reactor'
	implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-csv'
	implementation 'com.fasterxml.jackson.module:jackson-module-kotlin'
	implementation 'org.flywaydb:flyway-database-postgresql:11.1.0'
	implementation 'org.jetbrains.kotlin:kotlin-reflect'
	implementation 'org.postgresql:postgresql'
	implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
	implementation 'io.jsonwebtoken:jjwt-impl:0.11.5'
	implementation 'io.jsonwebtoken:jjwt-jackson:0.11.5'
	implementation 'io.sentry:sentry-spring-boot-starter-jakarta:8.6.0'
	implementation 'com.bucket4j:bucket4j_jdk17-core:8.15.0'
	implementation 'org.springframework.boot:spring-boot-starter-cache'
	implementation 'com.github.ben-manes.caffeine:caffeine'

	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'org.jetbrains.kotlin:kotlin-test-junit5'
	testImplementation 'org.springframework.security:spring-security-test'
	testImplementation 'org.mockito:mockito-core:5.9.0'
	testImplementation 'org.junit.jupiter:junit-jupiter:5.10.2'
	testImplementation 'org.mockito.kotlin:mockito-kotlin:5.3.1'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
	testRuntimeOnly 'com.h2database:h2'

}

kapt {
	arguments {
		arg("mapstruct.defaultComponentModel", "spring")
		arg("mapstruct.unmappedTargetPolicy", "IGNORE")
	}
	correctErrorTypes = true
}

kotlin {
	compilerOptions {
		freeCompilerArgs.addAll '-Xjsr305=strict'
	}
}

allOpen {
	annotation 'jakarta.persistence.Entity'
	annotation 'jakarta.persistence.MappedSuperclass'
	annotation 'jakarta.persistence.Embeddable'
}

tasks.named('test') {
	useJUnitPlatform()
}
tasks.withType(Test) {
	reports {
		junitXml.required = true  // Ensure XML reports are generated
		html.required = true      // Enable HTML reports
	}
}

// docker tasks
tasks.register('buildDockerImage', Exec) {
	dependsOn bootJar
	commandLine 'docker', 'build', '-t', 'harmony-backend:latest', '.'
}

tasks.register('runDockerContainer', Exec) {
	dependsOn buildDockerImage
	doFirst {
		// Remove any existing container
		exec {
			ignoreExitValue = true
			commandLine 'docker', 'rm', '-f', 'harmony-backend'
		}
	}
	commandLine 'docker', 'run', '--name', 'harmony-backend', '--rm', '-p', '8080:8080', '--env-file', '.env', 'harmony-backend:latest'
}

tasks.register('newMigration') {
	def templateFile = file('src/main/resources/templates/migration_template.sql')

	inputs.file(templateFile)

	doLast {
		def migrationsDir = file('src/main/resources/db/migration')
		def version = new Date().format('yyyyMMddHHmmss') // Timestamp for versioning
		def description = project.hasProperty('desc') ? project.desc : 'new_migration'
		def fileName = "V${version}__${description.replaceAll('\\s+', '_')}.sql"
		def migrationFile = new File(migrationsDir, fileName)

		if (!migrationsDir.exists()) {
			migrationsDir.mkdirs()
		}

		def templateContent
		if (templateFile.exists()) {
			templateContent = templateFile.text
		} else {
			println "Warning: Migration template not found at ${templateFile.path}. Using default content."
			templateContent = "-- Write your migration SQL here\n"
		}

		migrationFile.text = templateContent
		println "Created migration file: $migrationFile"
	}
}

// The task below prints the DB URL during gradle build for troubleshooting purposes
//tasks.register('printDatabaseUrl') {
//	doLast {
//		println "JDBC_DATABASE_URL: ${env.fetch('JDBC_DATABASE_URL')}"
//	}
//}
//buildDockerImage.dependsOn printDatabaseUrl
//bootRun.dependsOn printDatabaseUrl